class:: Slope
summary:: Slope of signal
categories:: UGens>Analysis, UGens>Filters>Linear, UGens>Maths

description::
Measures the rate of change per second of a signal.
Formula implemented is:

code::
out[i] = (in[i] - in[i-1]) * sampling_rate
::

classmethods::
method:: ar, kr
argument::in
Input signal to measure.
argument::mul
argument::add

examples::
code::
(
{
    var a, b, c, scale;
    a = LFNoise2.ar(2000);  // quadratic noise
    b = Slope.ar(a);        // first derivative produces line segments
    c = Slope.ar(b);        // second derivative produces constant segments
    scale = 0.0002; // needed to scale back to +/- 1.0
    [a, b * scale, c * scale.squared]
}.plot
)
::

For another example of Slope see link::Classes/AbstractFunction#hypot#AbstractFunction:hypot::.

