Qt 4.8: customwidgetplugin.pro Example File (designer/customwidgetplugin/customwidgetplugin.pro)

Qt Reference Documentation

- Qt 4.8
- ALL VERSIONS

- A
- A
- A
- Print

# customwidgetplugin.pro Example File

designer/customwidgetplugin/customwidgetplugin.pro

     CONFIG      += designer plugin
     TARGET      = $$qtLibraryTarget($$TARGET)
     TEMPLATE    = lib
     QTDIR_build:DESTDIR     = $$QT_BUILD_TREE/plugins/designer

     HEADERS     = analogclock.h \
                   customwidgetplugin.h
     SOURCES     = analogclock.cpp \
                   customwidgetplugin.cpp

     build_all:!build_pass {
         CONFIG -= build_all
         CONFIG += release
     }

     # install
     target.path = $$[QT_INSTALL_PLUGINS]/designer
     sources.files = $$SOURCES $$HEADERS *.pro
     sources.path = $$[QT_INSTALL_EXAMPLES]/designer/customwidgetplugin
     INSTALLS += target sources

     symbian: include($$QT_SOURCE_TREE/examples/symbianpkgrules.pri)
     maemo5: include($$QT_SOURCE_TREE/examples/maemo5pkgrules.pri)
     symbian: warning(This example does not work on Symbian platform)
     maemo5: warning(This example does not work on Maemo platform)
     simulator: warning(This example does not work on Simulator platform)