chown - change the owership on a list of files

- NAME
- SYNOPSIS
- DESCRIPTION

# NAME

chown - change the owership on a list of files

# SYNOPSIS

chown LIST

# DESCRIPTION

Changes the owner (and group) of a list of files. The first two elements of the list must be the numeric uid and gid, in that order. A value of -1 in either position is interpreted by most systems to leave that value unchanged. Returns the number of files successfully changed.

        $cnt = chown $uid, $gid, 'foo', 'bar';
        chown $uid, $gid, @filenames;

On systems that support fchown, you might pass file handles among the files. On systems that don't support fchown, passing file handles produces a fatal error at run time.

Here's an example that looks up nonnumeric uids in the passwd file:

        print "User: ";
        chomp($user = <STDIN>);
        print "Files: ";
        chomp($pattern = <STDIN>);

        ($login,$pass,$uid,$gid) = getpwnam($user)
            or die "$user not in passwd file";

        @ary = glob($pattern);      # expand filenames
        chown $uid, $gid, @ary;

On most systems, you are not allowed to change the ownership of the file unless you're the superuser, although you should be able to change the group to any of your secondary groups. On insecure systems, these restrictions may be relaxed, but this is not a portable assumption. On POSIX systems, you can detect this condition this way:

        use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
        $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);

chown - change the owership on a list of files