basic.pro Example File | Qt Virtual Keyboard 5.9

Qt 5.9 | Qt Virtual Keyboard | Qt Quick Virtual Keyboard - Basic Example | basic.pro Example File

Qt 5.9.2 Reference Documentation

# basic.pro Example File

basic/basic.pro

      TEMPLATE = app
      TARGET = basic
      QT += qml quick
      SOURCES += main.cpp
      CONFIG += link_pkgconfig
      static {
          QT += svg
          QTPLUGIN += qtvirtualkeyboardplugin
      }

      target.path = $$[QT_INSTALL_EXAMPLES]/virtualkeyboard/basic
      INSTALLS += target

      RESOURCES += \
          demo.qrc

      OTHER_FILES += \
          Basic.qml \
          basic-b2qt.qml \
          content/AutoScroller.qml \
          content/HandwritingModeButton.qml \
          content/ScrollBar.qml \
          content/TextArea.qml \
          content/TextBase.qml \
          content/TextField.qml \

      disable-xcb {
          message("The disable-xcb option has been deprecated. Please use disable-desktop instead.")
          CONFIG += disable-desktop
      }

      disable-desktop|android-embedded|!isEmpty(CROSS_COMPILE)|qnx {
          DEFINES += MAIN_QML=\\\"basic-b2qt.qml\\\"
      } else {
          DEFINES += MAIN_QML=\\\"Basic.qml\\\"
      }