worldtimeclockplugin.pro Example File | Qt Designer Manual

Qt 5.9 | Qt Designer Manual | World Time Clock Plugin Example | worldtimeclockplugin.pro Example File

Qt 5.9.2 Reference Documentation

# worldtimeclockplugin.pro Example File

worldtimeclockplugin/worldtimeclockplugin.pro

      QT          += widgets uiplugin

      QTDIR_build {
      # This is only for the Qt build. Do not use externally. We mean it.
      PLUGIN_TYPE = designer
      PLUGIN_CLASS_NAME = WorldTimeClockPlugin
      load(qt_plugin)
      CONFIG += install_ok
      } else {
      # Public example:

      TARGET      = $$qtLibraryTarget($$TARGET)
      CONFIG     += plugin
      TEMPLATE    = lib

      target.path = $$[QT_INSTALL_PLUGINS]/designer
      INSTALLS += target

      }

      HEADERS     = worldtimeclock.h \
                    worldtimeclockplugin.h
      SOURCES     = worldtimeclock.cpp \
                    worldtimeclockplugin.cpp