sidepanel.qml Example File | Qt Quick Controls 2 5.9

Qt 5.9 | Qt Quick Controls 2 | Qt Quick Controls 2 - Side Panel | sidepanel.qml Example File

Qt 5.9.3 Reference Documentation

# sidepanel.qml Example File

sidepanel/sidepanel.qml

      /****************************************************************************
      **
      ** Copyright (C) 2017 The Qt Company Ltd.
      ** Contact: https://www.qt.io/licensing/
      **
      ** This file is part of the examples of the Qt Toolkit.
      **
      ** $QT_BEGIN_LICENSE:BSD$
      ** Commercial License Usage
      ** Licensees holding valid commercial Qt licenses may use this file in
      ** accordance with the commercial license agreement provided with the
      ** Software or, alternatively, in accordance with the terms contained in
      ** a written agreement between you and The Qt Company. For licensing terms
      ** and conditions see https://www.qt.io/terms-conditions. For further
      ** information use the contact form at https://www.qt.io/contact-us.
      **
      ** BSD License Usage
      ** Alternatively, you may use this file under the terms of the BSD license
      ** as follows:
      **
      ** "Redistribution and use in source and binary forms, with or without
      ** modification, are permitted provided that the following conditions are
      ** met:
      **   * Redistributions of source code must retain the above copyright
      **     notice, this list of conditions and the following disclaimer.
      **   * Redistributions in binary form must reproduce the above copyright
      **     notice, this list of conditions and the following disclaimer in
      **     the documentation and/or other materials provided with the
      **     distribution.
      **   * Neither the name of The Qt Company Ltd nor the names of its
      **     contributors may be used to endorse or promote products derived
      **     from this software without specific prior written permission.
      **
      **
      ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
      ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
      ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
      ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
      ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
      ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
      ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
      ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
      ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
      ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
      ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
      **
      ** $QT_END_LICENSE$
      **
      ****************************************************************************/

      import QtQuick 2.6
      import QtQuick.Controls 2.2
      import QtQuick.Controls.Material 2.2

      ApplicationWindow {
          id: window
          width: 360
          height: 520
          visible: true
          title: qsTr("Side Panel")

          readonly property bool inPortrait: window.width < window.height

          ToolBar {
              id: overlayHeader

              z: 1
              width: parent.width
              parent: window.overlay

              Label {
                  id: label
                  anchors.centerIn: parent
                  text: "Qt Quick Controls 2"
              }
          }

          Drawer {
              id: drawer

              y: overlayHeader.height
              width: window.width / 2
              height: window.height - overlayHeader.height

              modal: inPortrait
              interactive: inPortrait
              position: inPortrait ? 0 : 1
              visible: !inPortrait

              ListView {
                  id: listView
                  anchors.fill: parent

                  headerPositioning: ListView.OverlayHeader
                  header: Pane {
                      id: header
                      z: 2
                      width: parent.width

                      contentHeight: logo.height

                      Image {
                          id: logo
                          width: parent.width
                          source: "images/qt-logo.png"
                          fillMode: implicitWidth > width ? Image.PreserveAspectFit : Image.Pad
                      }

                      MenuSeparator {
                          parent: header
                          width: parent.width
                          anchors.verticalCenter: parent.bottom
                          visible: !listView.atYBeginning
                      }
                  }

                  footer: ItemDelegate {
                      id: footer
                      text: qsTr("Footer")
                      width: parent.width

                      MenuSeparator {
                          parent: footer
                          width: parent.width
                          anchors.verticalCenter: parent.top
                      }
                  }

                  model: 10

                  delegate: ItemDelegate {
                      text: qsTr("Title %1").arg(index + 1)
                      width: parent.width
                  }

                  ScrollIndicator.vertical: ScrollIndicator { }
              }
          }

          Flickable {
              id: flickable

              anchors.fill: parent
              anchors.topMargin: overlayHeader.height
              anchors.leftMargin: !inPortrait ? drawer.width : undefined

              topMargin: 20
              bottomMargin: 20
              contentHeight: column.height

              Column {
                  id: column
                  spacing: 20
                  anchors.margins: 20
                  anchors.left: parent.left
                  anchors.right: parent.right

                  Label {
                      font.pixelSize: 22
                      width: parent.width
                      elide: Label.ElideRight
                      horizontalAlignment: Qt.AlignHCenter
                      text: qsTr("Side Panel Example")
                  }

                  Label {
                      width: parent.width
                      wrapMode: Label.WordWrap
                      text: qsTr("This example demonstrates how Drawer can be used as a non-closable persistent side panel.\n\n" +
                                 "When the application is in portrait mode, the drawer is an interactive side panel that can " +
                                 "be swiped open from the left edge. When the application is in landscape mode, the drawer " +
                                 "and the content are laid out side by side.\n\nThe application is currently in %1 mode.").arg(inPortrait ? qsTr("portrait") : qsTr("landscape"))
                  }
              }

              ScrollIndicator.vertical: ScrollIndicator { }
          }
      }