main.qml Example File | Qt Quick Controls 5.9

Qt 5.9 | Qt Quick Controls | Qt Quick Controls - UI Forms | main.qml Example File

Qt 5.9.4 Reference Documentation

# main.qml Example File

uiforms/main.qml

      /****************************************************************************
      **
      ** Copyright (C) 2016 The Qt Company Ltd.
      ** Contact: https://www.qt.io/licensing/
      **
      ** This file is part of the examples of the Qt Toolkit.
      **
      ** $QT_BEGIN_LICENSE:BSD$
      ** Commercial License Usage
      ** Licensees holding valid commercial Qt licenses may use this file in
      ** accordance with the commercial license agreement provided with the
      ** Software or, alternatively, in accordance with the terms contained in
      ** a written agreement between you and The Qt Company. For licensing terms
      ** and conditions see https://www.qt.io/terms-conditions. For further
      ** information use the contact form at https://www.qt.io/contact-us.
      **
      ** BSD License Usage
      ** Alternatively, you may use this file under the terms of the BSD license
      ** as follows:
      **
      ** "Redistribution and use in source and binary forms, with or without
      ** modification, are permitted provided that the following conditions are
      ** met:
      **   * Redistributions of source code must retain the above copyright
      **     notice, this list of conditions and the following disclaimer.
      **   * Redistributions in binary form must reproduce the above copyright
      **     notice, this list of conditions and the following disclaimer in
      **     the documentation and/or other materials provided with the
      **     distribution.
      **   * Neither the name of The Qt Company Ltd nor the names of its
      **     contributors may be used to endorse or promote products derived
      **     from this software without specific prior written permission.
      **
      **
      ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
      ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
      ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
      ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
      ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
      ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
      ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
      ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
      ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
      ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
      ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
      **
      ** $QT_END_LICENSE$
      **
      ****************************************************************************/

      import QtQuick 2.2
      import QtQuick.Layouts 1.1
      import QtQuick.Dialogs 1.1
      import QtQuick.Controls 1.2
      import io.qt.example 1.0
      import "qml"

      ApplicationWindow {
          visible: true
          title: "Qt Quick UI Forms"

          MessageDialog {
              id: aboutDialog
              icon: StandardIcon.Information
              title: qsTr("About")
              text: "Qt Quick UI Forms"
              informativeText: qsTr("This example demonstrates how to separate the implementation of an application from the UI using ui.qml files.")
          }

          Action {
              id: copyAction
              text: qsTr("&Copy")
              shortcut: StandardKey.Copy
              iconName: "edit-copy"
              enabled: (!!activeFocusItem && !!activeFocusItem["copy"])
              onTriggered: activeFocusItem.copy()
          }

          Action {
              id: cutAction
              text: qsTr("Cu&t")
              shortcut: StandardKey.Cut
              iconName: "edit-cut"
              enabled: (!!activeFocusItem && !!activeFocusItem["cut"])
              onTriggered: activeFocusItem.cut()
          }

          Action {
              id: pasteAction
              text: qsTr("&Paste")
              shortcut: StandardKey.Paste
              iconName: "edit-paste"
              enabled: (!!activeFocusItem && !!activeFocusItem["paste"])
              onTriggered: activeFocusItem.paste()
          }

          menuBar: MenuBar {
              Menu {
                  title: qsTr("&File")
                  MenuItem {
                      text: qsTr("E&xit")
                      shortcut: StandardKey.Quit
                      onTriggered: Qt.quit()
                  }
              }
              Menu {
                  title: qsTr("&Edit")
                  MenuItem {
                      action: cutAction
                  }
                  MenuItem {
                      action: copyAction
                  }
                  MenuItem {
                      action: pasteAction
                  }
              }
              Menu {
                  title: qsTr("&Help")
                  MenuItem {
                      text: qsTr("About...")
                      onTriggered: aboutDialog.open()
                  }
              }
          }

          MainForm {
              id: mainForm

              anchors.fill: parent

              Layout.minimumWidth: 800
              Layout.minimumHeight: 480
              Layout.preferredWidth: 768
              Layout.preferredHeight: 480

              tableView.model: CustomerModel

              Component.onCompleted: CustomerModel.selection = tableView.selection
          }
      }