Weitere spezielle Funktionen (Maxima Manual)

Vorige: Hypergeometrische Funktionen, Nach oben: Spezielle Funktionen [Inhalt][Index]

### 22.8 Weitere spezielle Funktionen

Funktion: li [s] (z) ¶

  Ist der Polylogarithmus der Ordnung s mit dem Argument z. Der Polylogarithmus wird durch die folgende Reihe definiert werden:

                                       inf
                                       ====   k
                                       \     z
                              Li (z) =  >    --
                                s      /      s
                                       ====  k
                                       k = 1

  Für s=1 geht der Polylogarithmus in die gewöhnliche Logarithmusfunktion über und man erhält `-log(1-z)`. Für s=2 oder s=3 spricht man vom Dilogarithmus oder Trilogarithmus.

  Maxima vereinfacht für s=1 sofort zum gewöhnlichen Logarithmus. Für negative ganze Zahlen s einschließlich der Null vereinfacht Maxima den Polylogarithmus zu einer rationalen Funktion.

  Ist s=2 oder s=3 und das Argument z eine Gleitkommazahl, vereinfacht Maxima den Di- oder Trilogarithmus zu einer Gleitkommazahl.

  Beispiele:

      (%i1) assume (x > 0);
      (%o1)                        [x > 0]
      (%i2) integrate ((log (1 - t)) / t, t, 0, x);
      (%o2)                       - li (x)
                                      2
      (%i3) li [2] (7);
      (%o3)                        li (7)
                                     2
      (%i4) li [2] (7), numer;
      (%o4)        1.24827317833392 - 6.113257021832577 %i
      (%i5) li [3] (7);
      (%o5)                        li (7)
                                     3
      (%i6) li [2] (7), numer;
      (%o6)        1.24827317833392 - 6.113257021832577 %i
      (%i7) L : makelist (i / 4.0, i, 0, 8);
      (%o7)   [0.0, 0.25, 0.5, 0.75, 1.0, 1.25, 1.5, 1.75, 2.0]
      (%i8) map (lambda ([x], li [2] (x)), L);
      (%o8) [0, .2676526384986274, .5822405249432515,
      .9784693966661848, 1.64493407, 2.190177004178597
       - .7010261407036192 %i, 2.374395264042415
       - 1.273806203464065 %i, 2.448686757245154
       - 1.758084846201883 %i, 2.467401098097648
       - 2.177586087815347 %i]
      (%i9) map (lambda ([x], li [3] (x)), L);
      (%o9) [0, .2584613953442624, 0.537213192678042,
      .8444258046482203, 1.2020569, 1.642866878950322
       - .07821473130035025 %i, 2.060877505514697
       - .2582419849982037 %i, 2.433418896388322
       - .4919260182322965 %i, 2.762071904015935
       - .7546938285978846 %i]

Funktion: specint (exp(- s*t) * expr, t) ¶

  Berechnet die Laplace-Transformation des Ausdrucks expr für die Integrationsvariable t. s ist der Parameter der Laplace-Transformation. Der Integrand expr kann spezielle Funktionen der Mathematik enthalten.

  Die folgenden speziellen Funktionen können als Integrand auftreten: die unvollständige Gammafunkion `gamma_incomplete`, die Fehlerfunktionen `erf` und `erfc`, nicht jedoch die Funktion `erfi`, die jedoch in eine andere Fehlerfunktion transformiert werden kann, die Exponentiellen Integrale wie zum Beispiel `expintegral_e1`, die Bessel-Funktionen wie zum Beispiel `bessel_j`, einschließlich der Produkte von Bessel-Funktionen, Hankel-Funktionen wie zum Beispiel `hankel_1`, Hermite `hermite` und Laguerre Polynome `laguerre`. Weiterhin kann `specint` Integranden mit der Hypergeometrische Funktion `%f[p,q]([],[],z)`, die Whittaker Funktion der ersten Art `%m[u,k](z)` und die der zweiten Art `%w[u,k](z)` integrieren.

  Das Ergebnis kann spezielle Funktionen und die Hypergeometrische Funktion enthalten.

  Kann die Funktion `laplace` keine Laplace-Transformation finden, wird `specint` aufgerufen. Da die Funktion `laplace` einige allgemeine Regeln kennt, um die Laplace-Transformation zu finden, ist es von Vorteil die Laplace-Transformation mit der Funktion `laplace` zu berechnen.

  `demo(hypgeo)` zeigt einige Beispiele für Laplace-Transformationen mit der Funktion `specint`.

  Beispiele:

      (%i1) assume (p > 0, a > 0)$
      (%i2) specint (t^(1/2) * exp(-a*t/4) * exp(-p*t), t);
                                 sqrt(%pi)
      (%o2)                     ------------
                                       a 3/2
                                2 (p + -)
                                       4

      (%i3) specint (t^(1/2) * bessel_j(1, 2 * a^(1/2) * t^(1/2))
                    * exp(-p*t), t);

                                         - a/p
                               sqrt(a) %e
      (%o3)                    ---------------
                                      2
                                     p

  Beispiel mit Exponentiellen Integralen.

      (%i4) assume(s>0,a>0,s-a>0)$
      (%i5) ratsimp(specint(%e^(a*t)
                            *(log(a)+expintegral_e1(a*t))*%e^(-s*t),t));

                                   log(s)
      (%o5)                        ------
                                   s - a

      (%i6) logarc:true$
      (%i7) gamma_expand:true$

      radcan(specint((cos(t)*expintegral_si(t)
                           -sin(t)*expintegral_ci(t))*%e^(-s*t),t));
                                   log(s)
      (%o8)                        ------
                                    2
                                   s  + 1
      ratsimp(specint((2*t*log(a)+2/a*sin(a*t)
                            -2*t*expintegral_ci(a*t))*%e^(-s*t),t));
                                     2    2
                                log(s  + a )
      (%o9)                     ------------
                                      2
                                     s

  Entwicklung der unvollständigen Gammafunktion und Wechsel in eine Darstellung mit dem Exponentiellen Integral `expintegral_e1`.

      (%i10) assume(s>0)$
      (%i11) specint(1/sqrt(%pi*t)*unit_step(t-k)*%e^(-s*t),t);
                                                  1
                                  gamma_incomplete(-, k s)
                                                  2
      (%o11)                      ------------------------
                                     sqrt(%pi) sqrt(s)

      (%i12) gamma_expand:true$
      (%i13) specint(1/sqrt(%pi*t)*unit_step(t-k)*%e^(-s*t),t);
                                    erfc(sqrt(k) sqrt(s))
      (%o13)                        ---------------------
                                           sqrt(s)

      (%i14) expintrep:expintegral_e1$
      (%i15) ratsimp(specint(1/(t+a)^2*%e^(-s*t),t));
                                    a s
                              a s %e    expintegral_e1(a s) - 1
      (%o15)                - ---------------------------------
                                              a

Funktion: hgfred (a, b, z) ¶

  Vereinfacht die Hypergeometrische Funktion zu einfacheren Funktionen, wie Polynome und spezielle Funktionen. Die Hypergeometrische Funktion ist die verallgemeinerte geometrische Reihe und ist wie folgt definiert:

         F    (a_1, ... a_p; b_1, ..., b_q; z) =
          p, q

                   inf      p                    q                k
                   ====   /===\ gamma(k + a )  /===\   gamma(b ) z
                   \       ! !             i    ! !           j
                 =  >      ! !  -------------   ! !  ----------------
                   /       ! !    gamma(a )     ! !  k! gamma(k + b )
                   ====   i = 1          i     j = 1               j
                   k = 0

  Die Argumente a und b sind Listen mit den Parametern der Hypergeometrischen Funktion `a_1`, …, `a_p` sowie `b_1`, …, `b_p`. Die Liste a enthält die `p`-Elemente a_i und die Liste b enthält die q-Elemente b_i.

  Kann `hgfred` die Hypergeomentrische Funktion nicht vereinfachen, wird eine Substantivform `%f[p,q]([a], [b], z)` zurückgegeben.

  Beispiele:

      (%i1) assume(not(equal(z,0)));
      (%o1)                          [notequal(z, 0)]
      (%i2) hgfred([v+1/2],[2*v+1],2*%i*z);

                           v/2                               %i z
                          4    bessel_j(v, z) gamma(v + 1) %e
      (%o2)               ---------------------------------------
                                             v
                                            z
      (%i3) hgfred([1,1],[2],z);

                                         log(1 - z)
      (%o3)                            - ----------
                                             z
      (%i4) hgfred([a,a+1/2],[3/2],z^2);

                                     1 - 2 a          1 - 2 a
                              (z + 1)        - (1 - z)
      (%o4)                   -------------------------------
                                       2 (1 - 2 a) z

Funktion: lambert_w (z) ¶

  Der Hauptzweig der Lambert W Funktion, die Lösung von `z = W(z) * exp(W(z))`.

Funktion: nzeta (z) ¶

  Die Plasma Dispersion Funktion `nzeta(z) = %i*sqrt(%pi)*exp(-z^2)*(1-erf(-%i*z))`.

Funktion: nzetar (z) ¶

  Gibt `realpart(nzeta(z))` zurück.

Funktion: nzetai (z) ¶

  Gibt `imagpart(nzeta(z))` zurück.

Funktion: %s [u,v] (z) ¶

  Lommels kleine Funktion `s[u,v](z)`. Siehe Gradshteyn & Ryzhik 8.570.1.

Vorige: Hypergeometrische Funktionen, Nach oben: Spezielle Funktionen [Inhalt][Index]