#!/usr/bin/env expect
############################################################################
# Purpose: Test of Slurm functionality
#          Validates that the smd -j (--job-info) display.
############################################################################
# Copyright (C) 2011-2014 SchedMD LLC
# Written by Nathan Yee <nyee32@schedmd.com>
# All rights reserved
############################################################################
source ./globals

set node_name   ""
set file_in     "test$test_id.script"
set job_id      0
set exit_code   0

proc cleanup {} {
	global job_id node_name bin_rm file_in

	cancel_job $job_id
	if {$node_name ne ""} {
		reset_state $node_name
	}

	exec $bin_rm -f $file_in
}

if {![param_contains [get_config_param "SlurmctldPlugstack"] "nonstop"]} {
	skip "This test is only compatible when SlurmctldPlugstack includes nonstop"
}
if {![is_super_user]} {
	skip "This test is only suitable for a super user (to restore down nodes)"
}

make_bash_script $file_in "$bin_sleep 100"

proc get_node {job_id} {
	global scontrol squeue re_word_str re_word_str

	set node_list ""
	spawn $squeue -j $job_id --noheader -o NodeList=%N
	expect {
		-re "NodeList=($re_word_str)" {
			set node_list $expect_out(1,string)
			exp_continue
		}
		timeout {
			fail "squeue is not responding"
		}
		eof {
			wait
		}
	}

	set node_name ""
	spawn $scontrol show hostnames $node_list
	expect {
		-re "($re_word_str)" {
			set node_name $expect_out(1,string)
			exp_continue
		}
		timeout {
			fail "scontrol is not responding"
		}
		eof {
			wait
		}
	}
	return $node_name
}

proc reset_state {node} {
	global scontrol

	spawn $scontrol update NodeName=$node State=RESUME
	expect {
		timeout {
			fail "scontrol is not responding"
		}
		eof {
			wait
		}
	}
}

#
# Submit batch script to test
#
set job_id 0
spawn $sbatch -N2 --no-kill -o /dev/null $file_in
expect {
	-re "Submitted batch job ($number)" {
		set job_id $expect_out(1,string)
		exp_continue
	}
	timeout {
		fail "sbatch is not responding"
	}
	eof {
		wait
	}
}
if {$job_id == 0} {
	log_error "sbatch did not submit job"
	set exit_code 1
}

#
# Wait for job to start
#
if {[wait_for_job $job_id "RUNNING"] != 0} {
        cancel_job $job_id
        fail "Waiting for job to start"
}
set node_name [get_node $job_id]

#
# Drain the node
#
set sub_match 0
spawn $smd -d $node_name $job_id -R test
expect {
	-re "Job $job_id node $node_name is being drained" {
		set sub_match 1
		exp_continue
	}
	timeout {
		fail "smd is not responding"
	}
	eof {
		wait
	}
}
if {$sub_match != 1} {
	log_error "smd did not drain node"
	set exit_code 1
}

#
# Now drop the node, which may extend our time limit
#
set sub_match 0
spawn $smd -D $node_name $job_id
expect {
	-re "Job $job_id node $node_name dropped" {
		set sub_match 1
		exp_continue
	}
	timeout {
		fail "smd is not responding"
	}
	eof {
		wait
	}
}
if {$sub_match != 1} {
	log_error "smd did not drain node"
	set exit_code 1
}

#
# Test the -j option
#
set sub_match 0
spawn $smd -j $job_id
expect {
	-re "Job $job_id .*" {
		set sub_match 1
		exp_continue
	}
	timeout {
		fail "smd is not responding"
	}
	eof {
		wait
	}
}
if {$sub_match != 1} {
	log_error "smd did not get information about the job"
	set exit_code 1
}

if {$exit_code != 0} {
	fail "Test failed due to previous errors (\$exit_code = $exit_code)"
}
