#!/usr/bin/env expect
############################################################################
# Purpose: Test of Slurm functionality
#          Validate scontrol requeuehold State=SpecialExit.
############################################################################
# Copyright (C) 2013 SchedMD LLC
# Written by Nathan Yee <nyee32@schedmd.com>
#
# This file is part of Slurm, a resource management program.
# For details, see <https://slurm.schedmd.com/>.
# Please also read the included file: DISCLAIMER.
#
# Slurm is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 2 of the License, or (at your option)
# any later version.
#
# Slurm is distributed in the hope that it will be useful, but WITHOUT ANY
# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
# FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
# details.
#
# You should have received a copy of the GNU General Public License along
# with Slurm; if not, write to the Free Software Foundation, Inc.,
# 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA.
############################################################################
source ./globals

set script             "test$test_id\.bash"
set job_id             0
set exit_code          0

proc cleanup {} {
	global bin_rm script job_id

	cancel_job $job_id
	exec $bin_rm -f $script
}

regexp "($number)" [get_config_param "MinJobAge"] {} min_age
if {$min_age < 10} {
	skip "MinJobAge too low for this test ($min_age < 10)"
}

# Remove any vestigial files
exec $bin_rm -f $script

make_bash_script $script "$bin_sleep 20"

proc check_release { job } {

	global scontrol number exit_code

	set priority 0
	spawn $scontrol show job $job
	expect {
		-re "Priority=($number)" {
			set priority $expect_out(1,string)
			exp_continue
		}
		timeout {
			fail "scontrol is not responding"
		}
		eof {
			wait
		}
	}

	if { $priority == 0 } {
		log_error "Priority was not set to a non zero value after it was released"
		set exit_code 1
	}
}

spawn $sbatch -N1 -t1 -o /dev/null -e /dev/null $script
expect {
	-re "Submitted batch job ($number)" {
		set job_id $expect_out(1,string)
		exp_continue
	}
	timeout {
		fail "sbatch is not responding"
	}
	eof {
		wait
	}
}

if { $job_id == 0 } {
	fail "sbatch did not submit job"
}

if {[wait_for_job $job_id "DONE"] != 0} {
	log_error "Error waiting for job $job_id to complete"
	cancel_job $job_id
	set exit_code 1
}

spawn $scontrol requeuehold State=SpecialExit $job_id
expect {
	timeout {
		fail "scontrol is not responding"
	}
	eof {
		wait
	}
}

if {![check_job_state $job_id SPECIAL_EXIT]} {
	log_error "Job was not on the desired state"
	set exit_code 1
}

spawn $scontrol release $job_id
expect {
	timeout {
		fail "scontrol is not responding"
	}
	eof {
		wait
	}
}

check_release $job_id

if {$exit_code != 0} {
	fail "Test failed due to previous errors (\$exit_code = $exit_code)"
}
