#!/usr/bin/env expect
############################################################################
# Purpose: Test of Slurm functionality
#          Test sbcast file overwrite (--force option).
#
# Note:    This script generates and then deletes files in the working directory
#          named test14.4.input, test14.4.output, and test14.4.error
############################################################################
# Copyright (C) 2006 The Regents of the University of California.
# Produced at Lawrence Livermore National Laboratory (cf, DISCLAIMER).
# Written by Morris Jette <jette1@llnl.gov>
# CODE-OCEC-09-009. All rights reserved.
#
# This file is part of Slurm, a resource management program.
# For details, see <https://slurm.schedmd.com/>.
# Please also read the included file: DISCLAIMER.
#
# Slurm is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 2 of the License, or (at your option)
# any later version.
#
# Slurm is distributed in the hope that it will be useful, but WITHOUT ANY
# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
# FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
# details.
#
# You should have received a copy of the GNU General Public License along
# with Slurm; if not, write to the Free Software Foundation, Inc.,
# 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA.
############################################################################
source ./globals

set file_in     "test$test_id.input"
set file_out    "test$test_id.output"
set file_err    "test$test_id.error"

proc cleanup {} {
	global bin_rm file_in file_out file_err

	exec $bin_rm -f $file_in $file_out $file_err
}

set exit_code            0
set skips                0
set job_id               0

if {[get_config_param "FrontendName"] ne "MISSING"} {
	skip "This test is incompatible with front-end systems"
}
if {[get_config_param "SlurmdUser"] ne "root(0)"} {
	skip "This test is incompatible with SlurmdUser != root"
}

#
# Delete left-over stdout/err files
# Build input script file that broacasts a file
# NOTE: we broadcast the file "sbcast", just for convenience
#
set pid         [pid]
set file1       "/tmp/test.$test_id.$pid.1"
set file2       "/tmp/test.$test_id.$pid.2"
exec $bin_rm -f $file_out $file_err
make_bash_script $file_in "
  echo '+++ Test 1 +++'
  $srun rm -f $file1
  $srun $bin_cp $sbatch $file1
  $sbcast $sbcast $file1
  $srun $bin_cmp $sbcast $file1
  $srun $bin_rm -f $file1

  echo '+++ Test 2 +++'
  $srun rm -f $file2
  $srun $bin_cp $sbatch $file2
  $sbcast $sbcast --force $file2
  $srun $bin_cmp $sbcast $file2
  $srun $bin_rm -f $file2
"

#
# Spawn an sbatch job that uses stdout/err and confirm their contents
# With multiple_slurmd we can face race conditions, so we limit the test
# to a single node, and we mark the test as partially skipped.
#
set timeout $max_job_delay
if {[get_config_param "MULTIPLE_SLURMD"] eq "Yes"} {
	incr skips
	set sbatch_pid [spawn $sbatch -N1 --output=$file_out --error=$file_err -t1 $file_in]
} else {
	set sbatch_pid [spawn $sbatch -N1-4 --output=$file_out --error=$file_err -t1 $file_in]
}
expect {
	-re "Submitted batch job ($number)" {
		set job_id $expect_out(1,string)
		exp_continue
	}
	timeout {
		slow_kill $sbatch_pid
		fail "srun not responding"
	}
	eof {
		wait
	}
}

if {$job_id == 0} {
	fail "Batch submit failure"
}

#
# Wait for job to complete and check output file
#
if {[wait_for_job $job_id "DONE"] != 0} {
	log_error "Waiting for job to complete"
	cancel_job $job_id
	set exit_code 1
}

set differ_found 0
if {[wait_for_file $file_out] == 0} {
	spawn $bin_cat $file_out
	expect {
		-re "$file1 differ" {
			set differ_found 1
			exp_continue
		}
		-re "$file2 differ" {
			log_error "sbcast failed to overwrite file with --force option"
			set exit_code 1
			exp_continue
		}
		eof {
			wait
		}
	}
}
if {$differ_found == 0} {
	fail "sbcast overwrote file without --force option"
}

if {$exit_code != 0} {
	fail "Test failed due to previous errors (\$exit_code = $exit_code)"
}

if {$skips} {
	skip "This test is partially compatible with multiple slurmd systems"
}
